#
# Commodore 64 ART (Art Studio) hires exporter
# A Multipaint internal script
#

XREM "Art Studio header"

XBYTE 0,32

XREM "Bitmap"

FOR Y=0 TO 24
	FOR X=0 TO 39
		FOR V=0 TO 7
			C=128
			L=0
			FOR B=0 TO 7
				P=V*320
				P=P+B
				M=X*8
				P=P+M
				M=Y*2560
				P=P+M
				P=P+1024
				O=PEEK P
				M=C*O
				L=L+M
				C=C/2
			NEXT B
			XBYTE L
		NEXT V
	NEXT X
NEXT Y

XREM "Colors"

FOR Y=0 TO 24
	FOR X=0 TO 39
		P = Y*320
		P = P+X
		P = P+65536
		H = PEEK P
		P = P+8000
		L = PEEK P
		M = H*16
		A = M+L
		XBYTE A
	NEXT X
NEXT Y

XREM "Border"

B = PEEK 0

XBYTE B

XREM "Footer"

XBYTE 77,32,39,83,84,85

# Write to file (9009 bytes)

SAVE
